pro xyouts_noaa_over,date_obs,pangle=pangle,narlist=narlist,xylist=xylist, $
                     count=count,noread=noread,noplot=noplot,_extra=extra

;+
;
; Name        : xyouts_noaa_over
;
; Purpose     : Output NOAA number on the extisting map plot.
;
; Syntax      : IDl> plot_map, map ; Plotting any map
;               IDL> xyouts_noaa_over,date_obs,[pangle=pangle], $
;                      [narlist=narlist],[xylist=xylist],[count=count], $
;                      [/noread],[/noplot]
;
; Input       : date_obs = observation date and time (in any format)
;               pangle   = solar polar angle in degree (CCW->+)
;               narlist  = (with noread keyword) given NOAA information.
;
; Output      : narlist  = structure array including information of each
;                          extisting active region.
;                          see NAR_Data in gbo.struct.pro for more information.
;               xylist   = positions of active regions with solar rotation.
;               count    = number of active regions
;
; Keyword     : noread   = just plotting NOAA number using given narlist.
;               noplot   = without plotting NOAA number
;
; Comment     : Any keywords for xyouts.pro and get_nar.pro are acceptable.
;
; History     : Written  1-Oct-2013 - by K. Otsuji
;               Modified 3-Oct-2013 - by K. Otsuji
;
;-

tai10000=anytim2tai('2002-06-01')
if not keyword_set(noread) then narlist=get_nar(date_obs,_extra=extra)

if size(narlist[0],/type) eq 7 then count=0 else $
   ok=where(narlist.NUM_SPOTS ge 1,count)

if count ne 0 then xylist=fltarr(2,count)

for j=0,count-1 do begin
  nar=narlist[ok[j]]

  time=anytim(nar,/ccsds)
  noaa=nar.NOAA
  noaa+=10000*(noaa le 9000 and anytim2tai(time) ge tai10000 $
               and not keyword_set(noread))
  narlist[j].NOAA=noaa
  loc=nar.location

  xy=hel2arcmin(loc[1],loc[0],date=time)*60.
  drot_xy,xy[0],xy[1],time,date_obs,x0,y0
  if isvalid(pangle) then roll_xy,x0,y0,-pangle,x0,y0
  if ~keyword_set(noplot) then xyouts,x0,y0+100,strtrim(noaa,2), $
                                      align=0.5,_extra=extra
  xylist[0,j]=[x0,y0]
endfor

if count eq 0 then $
  print,'There is no active region on the specified date.'

end