pro norh_fujiki,rawfile,szfile,frame $
   ,imgdir=imgdir $
   ,outfile=outfile,rlphdiffile=rlphdiffile $
   ,version=version,freq=freq $
   ,cenfnl=cenfnl,cenunit=cenunit $
   ,nfrcal=nfrcal,nfrint=nfrint $
   ,ref_frame=ref_frame,ref_nfrcal=ref_nfrcal $
   ,clcra=clcra,clcrs=clcrs,clcrfac=clcrfac $
   ,clc2a=clc2a,clc2s=clc2s $
   ,winsize=winsize,clgain=clgain

;+
; NAME:
;       NORH_FUJIKI
;
; PURPOSE:
;       This procedure gives a front-end for synthesizing
;       the NORH images from the raw data by the 'Fujiki'
;       program.
;
; CALLING SEQUENCE:
;       norh_fujiki,rawfile,szfile,frame
;
; INPUTS:
;       rawfile: Raw-data file for synthesizing
;       szfile: 'SZ' file corresponding to the raw-data file
;       frame: frame ID number to be synthesized
;       
; OPTIONAL INPUT KEYWORDS:
;
;    *Version
;       version: version of synthesizing program.
;                Newest if given '-1'. 
;                '3','4','6.0', '6.1' or '6.2' are available for 'fujiki'.
;
;    *Data
;       outfile: input-parameter file for synthesizing
;       rlphdiffile: phase-difference-table file
;       imgdir: Image-data file name
;       nfrint:  Number of frames for integration (default 1)
;
;    *Field of View
;       Image pixel size is fixed to (128,128) in 'fujiki'.
;       cenfnl:   Position of Sun center relative to the image center
;                 Default is (0,0).
;       cenunit:  Unit ID for 'cenfnl' [1: arcsec(default); 2: pixel]
;
;    *Calibration
;       nfrcal:  Number of frames used for calibration (default 1)
;       ref_frame:
;       ref_nfrcal:
;
;    *CLEAN paramters
;       clcra:   CLEAN criterion for (r+l) (default 3000)
;       clcrs:   CLEAN criterion for (r-l) (default 3000)
;       clcrfac:
;       winsize:
;       clc2a:   pre-CLEAN criterion for (r+l) (default 3000)
;       clc2s:   pre-CLEAN criterion for (r-l) (default 3000)
;       pre_clcra: pre-CLEAN criterion for (r+l) (default 3000)
;
; HISTORY:
;       Written 1998-11-12 TY
;       Modified 1999-6-30 TY for ver6.2
;       Modified 1999-12-27 TY ref_frame0
;       Modified 2001-1-12 TY for bug print,frame,format
;       Modified 2001-3-06 TY for ver6.3
;
;-

if (n_elements(outfile) eq 0) then outfile=curdir()+'/'+'norh_synth_input'
if (n_elements(imgdir) eq 0) then imgdir=curdir()+'/'

if (n_elements(version) eq 0) then version='-1'
if (version eq '-1') then version='6.2'
if (n_elements(freq) eq 0) then freq=17

if (n_elements(size) eq 0) then size=512
if (n_elements(cenunit) eq 0) then cenunit=1 else begin
  case strtrim(cenunit,2) of
    'arcsec': cenunit=1
    'pixel': cenunit=2 
    '1': cenunit=1
    '2': cenunit=2
  endcase
endelse  
if (n_elements(cenfnl) eq 0) then cenfnl=[0,0]

if (n_elements(nfrcal) eq 0) then nfrcal=1
if (n_elements(nfrint) eq 0) then nfrint=1

if (n_elements(clcra) eq 0) then clcra=3000
if (n_elements(clcrs) eq 0) then clcrs=3000
if (n_elements(clc2a) eq 0) then clc2a=3000
if (n_elements(clc2s) eq 0) then clc2s=3000
if (n_elements(clcrfac) eq 0) then clcrfac=0.01

if (n_elements(ref_nfrcal) eq 0) then ref_nfrcal=1
if (n_elements(ref_nfrint) eq 0) then ref_nfrint=1
if (n_elements(ref_frame) eq 0) then ref_frame0=frame(0) $
  else ref_frame0=ref_frame

if (n_elements(pre_clcra) eq 0) then pre_clcra=clcra
if (n_elements(winsize) eq 0) then winsize=9
if (n_elements(clgain) eq 0) then clgain=0.2

nfrina=1

mfrx=n_elements(frame)

case 1 of
  (version eq '3') : begin
   if (freq eq 17) then begin
    cencoord=cenfnl+[256,256]
    openw,unit,outfile,/get_lun
      printf,unit,rawfile
      printf,unit,szfile
      printf,unit,rlphdiffile
      printf,unit,ref_frame0
      printf,unit,ref_nfrcal
      printf,unit,ref_nfrint
      printf,unit,0
      printf,unit,mfrx
      printf,unit,format='(10(i6))',frame
      printf,unit,nfrcal
      printf,unit,nfrint
      printf,unit,nfrina
      printf,unit,cencoord
      printf,unit,clcra
      printf,unit,clcrs
      printf,unit,winsize
      printf,unit,clgain
      printf,unit,imgdir
      printf,unit,0
      printf,unit,pre_clcra
    close,unit
    free_lun,unit
   endif else begin
    message,'Sorry, this version only supports 17GHz data'
   endelse
  end
  (version eq '4') or (version eq '6.0') : begin
   if (freq eq 17) then begin
    openw,unit,outfile,/get_lun
      printf,unit,rawfile
      printf,unit,szfile
      printf,unit,rlphdiffile
      printf,unit,ref_frame0
      printf,unit,ref_nfrcal
      printf,unit,ref_nfrint
      printf,unit,0
      printf,unit,mfrx
      printf,unit,format='(10(i6))',frame
      printf,unit,nfrcal
      printf,unit,nfrint
      printf,unit,cenunit,cenfnl
      printf,unit,clcra,clcrs
      printf,unit,clc2a,clc2s
      printf,unit,clcrfac
      printf,unit,winsize
      printf,unit,imgdir
    close,unit
    free_lun,unit
   endif else begin
    message,'Sorry, this version only supports 17GHz data'
   endelse
  end
  (version eq '6.1') or (version eq '6.2') : begin
   if (freq eq 17) then begin
    openw,unit,outfile,/get_lun
      printf,unit,imgdir
      printf,unit,rawfile
      printf,unit,szfile
      printf,unit,cenunit,cenfnl
      printf,unit,0
      printf,unit,mfrx
      printf,unit,format='(10(i6))',frame
      printf,unit,nfrcal
      printf,unit,nfrint
      printf,unit,ref_frame0
      printf,unit,ref_nfrcal
      printf,unit,ref_nfrint
      printf,unit,clcra,clcrs
      printf,unit,clc2a,clc2s
      printf,unit,clcrfac
    close,unit
    free_lun,unit
   endif else begin
    message,'Sorry, this version only supports 17GHz data'
   endelse
  end
  (version eq '6.3') : begin
   if (freq eq 17) then begin
    openw,unit,outfile,/get_lun
      printf,unit,imgdir
      printf,unit,rawfile
      printf,unit,szfile
      printf,unit,cenunit,cenfnl
      printf,unit,0
      printf,unit,mfrx
      printf,unit,format='(10(i6))',frame
      printf,unit,nfrint
      printf,unit,nfrcal,ref_frame0,ref_nfrcal
      printf,unit,clcra,clcrs
      printf,unit,clc2a,clc2s
      printf,unit,clcrfac
    close,unit
    free_lun,unit
   endif else begin
    message,'Sorry, this version only supports 17GHz data'
   endelse
  end
endcase





return
end