pro norh_trans,arg0,arg1,arg2 $
  ,norun=norun,usetsx=usetsx,rawdir=rawdir,outfile=outfile $
  ,freq=freq,event=event

;+
; NAME:
;       NORH_TRANS
;
; PURPOSE:
;       This procedure transfers the raw-data files of NORH 
;       from the archive to the user's local directory.
;
; CALLING SEQUENCE:
;       norh_trans,st_time,ed_time,interval
;       norh_trans,times
;
; INPUTS:
;       st_time:  Start time of the observing sequence.
;                 An n-element vector of time.
;                 Any formats supported by 'anytim' function
;                 is accepted.
;                  (1) structure wit a .time and .day field, or
;                  (2) 2xN where the first dimension holds (MSOD, DS79), or
;                  (3) a double or float array of seconds from 1-jan-79, or
;                  (4) string, e.g.
;                   '1992-11-05 12:33:00' (NORH)
;                   '1992-11-05T12:33:00Z' (ISO 8601)
;                   '12:33:00 5-nov-92' (Yohkoh)
;                   '92/11/05 12:33:00' (HXRBS)
;                   etc.
;       ed_time:  End time of the sequence.
;                 An n-element vector of time.
;       interval: Interval of the obseving sequence in units of 'second'.
;                 An n-element vector of integer.
;       times: Time of requested data sequence.
;             Non-uniform interval is accepted.
;
; OPTIONAL INPUT KEYWORDS:
;       rawdir: Destination of requested files.
;               Default is the current directory.
;       event:  event mode data
;       freq:   Observing frequency of the data.
;               '17' or '34'. Default is '17'.
;       outfile: Parameter file name for transfer shell script.
;               Default is 'norh_trans_input'.
;       norun: Set if you only need the parameter file and
;              do not want really transfer yet.
;       usetsx:  use 'tsx' file for finding the synthesizing frame
;                instead of 'info'
;
; HISTORY:
;       Writtern 1998-05-29 JS and TY
;       Modified 1999-1-14 TY for useinfo option
;       Modified 1999-02-04 TY /event support
;
;-

;if (n_elements(rawdir) eq 0) then  rawdir=curdir()
;if (n_elements(freq) eq 0) then freq=17
if keyword_set(usetsx) then useinfo=0 else useinfo=1

case n_params() of
  3: begin
    st_time=arg0 & ed_time=arg1 & interval=arg2
    dayfr=norh_tim2f(st_time,ed_time,interval $
     ,event=event,freq=freq,useinfo=useinfo)
  end
  1: begin
    time=arg0 
    dayfr=norh_tim2f(time,useinfo=useinfo,event=event)
  end
  else: message,'Wrong number of arguments'
endcase
norh_trans_byf,dayfr,freq=freq,rawdir=rawdir,outfile=outfile $
  ,norun=norun,event=event

return
end