pro tykw_rd_0pa,file,rd0pa

;+
; NAME:
;       TYKW_RD_0PA
;
; PURPOSE:
;       This procedure is for reading the 0P0A calibration data of TYKW.
;
; CALLING SEQUENCE:
;       tykw_rd_0pa,file,rd0pa
;
; INPUTS:
;       file: file name of TYKW 0P0A data
;
; OPTIONAL INPUT KEYWORDS:
;
; OUTPUTS:
;       rd0pa: structure of the 0P0A data
;
; HISTORY:
;    4/6/79        ver.0.0 K. Shibasaki as fortran program
;    Sep. 09, 1994 ver.1.0 M. Nishio
;    Jan. 10, 1995 ver.2.0 M. Nishio
;    Apr. 13, 1995 ver.3.2 M. Nishio
;    Apr. 13, 1995 ver.4.0 M. Nishio
;    May. 23, 1995 ver.5.0 M. Nishio
;    May  01, 1995 ver.5.2 M. Nishio
;    Apr. 25, 1995 ver.5.0 M. Nishio
;
;    1999-01-12 ported to IDL by TY
;    2006-02-15 added swap_endian for x86 system by MS
;    2013-09-02 added swap_endian for x86_64 system by MS
;
;-

inrec = { dt0pa, dleng: long(0), ymd: lonarr(3), freq: long(0), $
       data: fltarr(5000), $
       flux: float(0), trange: lonarr(2), intt: fltarr(5,2), $
       ambi: float(0), dummy1: long(0), zeroi: float(0), $
       skyi: float(0), suni: float(0), $
       ambv: float(0), dummy2: long(0), zerov: float(0), $
       skyv: float(0), sunv: float(0), $
       at: fltarr(5), dummy3: lonarr(12), $
       termnator: long(0), dummy: lonarr(5046)}

rd0pa=  replicate( {dt0pa} , 4 )

if ((!version.arch eq 'x86') or (!version.arch eq 'x86_64'))then begin ; swap endian
  openr, uin, file,/get_lun,/swap_endian
  readu, uin, rd0pa
  free_lun,uin
endif else begin
  openr, uin, file,/get_lun
  readu, uin, rd0pa
  free_lun,uin
endelse

for m=0,3 do begin
  whr=where(rd0pa(m).data ge 1.d38,count)
  if (count ne 0) then rd0pa(m).data(whr)=0.
endfor


return
end