pro norh_rd_rdt17,file,rdata,header

;+
; NAME:
;       NORH_RD_RDT17
;
; PURPOSE:
;       This procedure is for reading the raw data of NoRH.
;
; CALLING SEQUENCE:
;       norh_rd_rdt,file,rdata,header
;
; INPUTS:
;       file: file name of NoRH raw data
;
; OPTIONAL INPUT KEYWORDS:
;
; OUTPUTS:
;       rdata: structure of the raw data
;       header: header of the data
;
; HISTORY:
;       by T. Yokoyama 2000.6.15
;-

header={norhhd, $
date: '      ', $
fstatus: ' ', $    ; 1:with data drop, 2:without data drop
dummy: byte(0), $
st_frame: long(0), $
ed_frame: long(0), $
st_time: '      ', $
ed_time: '      ', $
flag: strarr(600)+' ', $ ; 0:NoData, 1:Calib, 2:Data, 3:EventData
fnl_frame: long(0), $
fnl_flag: ' ', $
rfu: bytarr(28248L-633) $
}

dt_el={norhdt, $
frame: long(0), $
time: bytarr(8), $
status1: bytarr(2), $
status2: bytarr(6), $
amp_R: intarr(84), $
cor_R: intarr(2,84*83/2), $ ; (Real,Imaginary) * AntPairs
amp_L: intarr(84), $
cor_L: intarr(2,84*83/2), $
dummy: bytarr(4) $
}

openr,unit,file,/get_lun

tmp=FSTAT(unit)
filesize=tmp.size
n_record=filesize/28248L

rdata = replicate( {norhdt} , n_record-1 ) 

readu,unit,header
readu,unit,rdata

free_lun,unit

return
end