pro norh_synth,arg0,arg1,arg2 $
   ,norun=norun,host=host,queue=queue,usetsx=usetsx $
   ,freq=freq,event=event,prog=prog,version=version $
   ,outfile=outfile,imgdir=imgdir $
   ,usewk=usewk,useac=useac,usead=usead,szfile=szfile,rawdir=rawdir $
   ,nfrint=nfrint $
   ,cenunit=cenunit,cenfnl=cenfnl,size=size $
   ,clcrfac=clcrfac,clcra=clcra,clcrs=clcrs $
   ,clc2a=clc2a,clc2s=clc2s $
   ,nfrcal=nfrcal,ref_frame=ref_frame,ref_nfrcal=ref_nfrcal

;+
; NAME:
;       NORH_SYNTH
;
; PURPOSE:
;       This procedure gives a front-end for synthesizing 
;       the NORH images from the raw data. A synthesizing job
;       is invoked on the supercomputer system in NSRO
;       after calling this procedure.
;
; CALLING SEQUENCE:
;       norh_synth,st_time,ed_time,interval
;       norh_synth,times
;
; INPUTS:
;       st_time:  Start time of the observing sequence.
;                 An n-element vector of time.
;                 Any formats supported by 'anytim' function
;                 is accepted.
;                  (1) structure wit a .time and .day field, or
;                  (2) 2xN where the first dimension holds (MSOD, DS79), or
;                  (3) a double or float array of seconds from 1-jan-79, or
;                  (4) string, e.g.
;                   '1992-11-05 12:33:00' (NORH)
;                   '1992-11-05T12:33:00Z' (ISO 8601)
;                   '12:33:00 5-nov-92' (Yohkoh)
;                   '92/11/05 12:33:00' (HXRBS)
;                   etc.
;       ed_time:  End time of the sequence.
;                 An n-element vector of time.
;       interval: Interval of the obseving sequence in units of 'second'.
;                 An n-element vector of string.
;       times: Time of requested data sequence.
;             Non-uniform interval is accepted.
;
; OPTIONAL INPUT KEYWORDS:
;       prog:   The program for synthesizing.
;               'hanaoka', 'koshix' or 'fujiki' is available.
;               Default is 'hanaoka'.
;       rawdir: Directry of the raw-data files
;               Default is the current directory.
;       imgdir: Directory for synthesized image files.
;               Default is the current directory.
;       event:  event mode data
;       freq:   Observing frequency of the data.
;               '17' or '34'. Default is '17'.
;       outfile: Parameter file name for synthesize shell script.
;               Default is 'norh_synth_input'.
;       norun: Set if you only need the parameter file and
;              do not want really run yet.
;       usetsx:  use 'tsx' file for finding the synthesizing frame
;                instead of 'info'
;
; HISTORY:
;       Writtern 1998-05-29 JS and TY
;       Modified 1998-11-12 TY for non-NSRO user support
;       Modified 1998-11-12 TY for Fujiki support
;       Modified 1999-1-14 TY for useinfo option
;       Modified 1999-02-04 TY /event support
;
;-


if (n_elements(outfile) eq 0) then outfile=curdir()+'/'+'norh_synth_input'
if (n_elements(rawdir) eq 0) then  rawdir=curdir()
if (n_elements(freq) eq 0) then freq=17
if (n_elements(interval) eq 0) then interval='1'
if (n_elements(imgdir) eq 0) then imgdir=curdir()
if keyword_set(usetsx) then useinfo=0 else useinfo=1


case n_params() of
  3: begin
    st_time=arg0 & ed_time=arg1 & interval=arg2
    dayfr=norh_tim2f(st_time,ed_time,interval $
     ,event=event,freq=freq,useinfo=useinfo)
  end
  1: begin
    time=arg0
    dayfr=norh_tim2f(time,useinfo=useinfo,event=event)
  end
  else: message,'Wrong number of arguments'
endcase

norh_synth_byf,dayfr $
   ,norun=norun,host=host,queue=queue $
   ,freq=freq,event=event,prog=prog,version=version $
   ,outfile=outfile,imgdir=imgdir $
   ,usewk=usewk,useac=useac,usead=usead,szfile=szfile,rawdir=rawdir $
   ,nfrcal=nfrcal,nfrint=nfrint $
   ,cenunit=cenunit,cenfnl=cenfnl,size=size $
   ,clcrfac=clcrfac,clcra=clcra,clcrs=clcrs $
   ,clc2a=clc2a,clc2s=clc2s $
   ,ref_frame=ref_frame,ref_nfrcal=ref_nfrcal

return
end